Upload-Tasks für Plugin und Bridge

bridge/build.gradle

@@ -44,3 +44,24 @@ tasks.named('run') {
     workingDir = rootProject.file('run/bridge')
     doFirst { workingDir.mkdirs() }
 }
+
+// Hochladen auf 10.20.9.3: ./gradlew :bridge:uploadBridge, danach `sudo systemctl restart voicebridge`.
+// Erst in eine Temp-Datei, Prüfsumme vergleichen, dann atomar umbenennen.
+tasks.register('uploadBridge') {
+    dependsOn shadowJar
+    doLast {
+        def file = shadowJar.archiveFile.get().asFile
+        def checksum = file.bytes.digest('SHA-256')
+        def target = '/home/minecraft/voicebridge/voice-bridge.jar'
+        providers.exec {
+            commandLine 'ssh', 'minecraft@10.20.9.3', 'mkdir -p /home/minecraft/voicebridge'
+        }.result.get()
+        providers.exec {
+            commandLine 'scp', file.absolutePath, "minecraft@10.20.9.3:${target}.new"
+        }.result.get()
+        providers.exec {
+            commandLine 'ssh', 'minecraft@10.20.9.3',
+                "echo '${checksum}  ${target}.new' | sha256sum -c --quiet && mv -f ${target}.new ${target}"
+        }.result.get()
+    }
+}

plugin/build.gradle

@@ -29,3 +29,21 @@ jar {
     dependsOn ':protocol:jar'
     from(project(':protocol').sourceSets.main.output)
 }
+
+// Hochladen auf den Paper-Server: ./gradlew :plugin:uploadPlugin, danach Paper neu starten.
+// Erst in eine Temp-Datei, Prüfsumme vergleichen, dann atomar umbenennen.
+tasks.register('uploadPlugin') {
+    dependsOn jar
+    doLast {
+        def file = jar.archiveFile.get().asFile
+        def checksum = file.bytes.digest('SHA-256')
+        def target = '/home/minecraft/server/plugins/voice-bridge.jar'
+        providers.exec {
+            commandLine 'scp', file.absolutePath, "minecraft@10.20.9.3:${target}.new"
+        }.result.get()
+        providers.exec {
+            commandLine 'ssh', 'minecraft@10.20.9.3',
+                "echo '${checksum}  ${target}.new' | sha256sum -c --quiet && mv -f ${target}.new ${target}"
+        }.result.get()
+    }
+}