//for jar packaging see https://github.com/Protonull/BasicMinestomServer/blob/master/build.gradle.kts

plugins {
    id 'java'
    id "com.gradleup.shadow" version "9.6.0"
}

group 'eu.mhsl.minenet'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(25)
    }
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter:6.1.2'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

    //https://mvnrepository.com/artifact/net.minestom/minestom
    implementation 'net.minestom:minestom:2026.07.12-26.2'

    //Tools
    implementation 'de.articdive:jnoise-pipeline:4.1.0'
    compileOnly 'it.unimi.dsi:fastutil:8.5.18' // von Minestom nur zur Laufzeit bereitgestellt, fuer BatchUtil-Reflection benoetigt
    implementation 'net.md-5:bungeecord-config:1.21-R0.3'
    implementation 'org.apache.commons:commons-text:1.15.0'
    implementation 'org.spongepowered:configurate-yaml:4.2.0'
    implementation 'com.sparkjava:spark-core:2.9.4'
    implementation 'com.google.code.gson:gson:2.14.0'
    implementation 'com.google.guava:guava:33.4.8-jre'

    //PvP
    implementation 'io.github.togar2:MinestomPvP:2026.05.30-26.1.1'
}

tasks {
    jar {
        manifest {
            attributes 'Main-Class': 'eu.mhsl.minenet.minigames.Main'
            attributes 'Multi-Release': true
        }
    }
    build {
        dependsOn(shadowJar)
    }
    shadowJar {
        mergeServiceFiles()
        archiveClassifier.set("")
    }
}

tasks.register('copyJarToServer', Exec) {
    dependsOn shadowJar
    mustRunAfter shadowJar

    commandLine 'scp', 'build/libs/Minigames-1.0-SNAPSHOT.jar', 'root@10.20.6.5:/root/minigames'
}